#version 330 core

struct Material {
  sampler2D diffuse;
  vec3 specular;
  float shininess;
};

struct Light {
  vec3 position;
  vec3 ambient;
  vec3 diffuse;
  vec3 specular;
};

in vec3 vert_normal;
in vec3 frag_position;
in vec2 uv_coords;

out vec4 color;

uniform Material material;
uniform Light light;
uniform vec3 camera_position;

void main() {
  float ambient_strength   = 0.15;
  float specular_strength  = 0.5;
  vec3  normal             = normalize(vert_normal);
  vec3  light_direction    = normalize(light.position - frag_position);
  vec3  view_direction     = normalize(camera_position - frag_position);
  vec3  reflect_direction  = reflect(-light_direction, normal);
  float diff               = max(dot(normal, light_direction), 0.0);
  float spec               = pow(max(dot(reflect_direction, view_direction), 0.0), material.shininess);
  vec3  diff_tex           = vec3(texture(material.diffuse, uv_coords));
  vec3  ambient            = light.ambient * diff_tex;
  vec3  diffuse            = light.diffuse * (diff * diff_tex);
  vec3  specular           = light.specular * (spec * material.specular);

  color = vec4(ambient + diffuse + specular, 1.0);
};